commit: 7760d0c9d415604095494c4b5318d0839af5263d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 15 04:56:00 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan 15 04:56:00 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7760d0c9
dev-python/nbclassic: Bump to 1.2.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/nbclassic/Manifest | 1 +
dev-python/nbclassic/nbclassic-1.2.0.ebuild | 74 +++++++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
index 293fdc9514a0..8fd3f9fd7663 100644
--- a/dev-python/nbclassic/Manifest
+++ b/dev-python/nbclassic/Manifest
@@ -1 +1,2 @@
DIST nbclassic-1.1.0.tar.gz 20194834 BLAKE2B
7fe5e3d405964faf09a6f58b54d03dae7ec661e276d5e26e71e054b277f99db61dd7ef0c3ec2417230ea7d724814a4919514b4274772b5a73a89d0c59db09468
SHA512
a5348ff7bff944c12745111fcf64ca92d75bf7bc063d51baf04bc8894473ba0689ec4420ff1ce2d2a40601b55d14a1cd257215cd4f11839fa47e8ea93933268d
+DIST nbclassic-1.2.0.tar.gz 20204389 BLAKE2B
37d2614b48e28d187b7f22aeab71bb5b1d8dbc0349654bbd8323a76bb6cd789ed6bd3d0c04764e6e9757d37df1131dde3fe3927d1933de6b9e2db2d4651e00b9
SHA512
416345cb773392b4d2b03a914ed3511bf75a7ea8dad02360a0623233af56f38a9853647ad1b62f0f7e397e6b3715bd66bc5e52e4736fe5b30884136fab0b459c
diff --git a/dev-python/nbclassic/nbclassic-1.2.0.ebuild
b/dev-python/nbclassic/nbclassic-1.2.0.ebuild
new file mode 100644
index 000000000000..28e6cbb5ed5a
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-1.2.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+DISTUTILS_USE_PEP517=jupyter
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+ https://jupyter.org/
+ https://github.com/jupyter/nbclassic/
+ https://pypi.org/project/nbclassic/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+ dev-python/ipykernel[${PYTHON_USEDEP}]
+ dev-python/ipython-genutils[${PYTHON_USEDEP}]
+ >=dev-python/nest-asyncio-1.5[${PYTHON_USEDEP}]
+ >=dev-python/notebook-shim-0.2.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ test? (
+ dev-python/nbval[${PYTHON_USEDEP}]
+ dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+ dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+ dev-python/testpath[${PYTHON_USEDEP}]
+ )
+ doc? (
+ virtual/pandoc
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+ dev-python/pydata-sphinx-theme \
+ dev-python/nbsphinx \
+ dev-python/sphinxcontrib-github-alt \
+ dev-python/myst-parser \
+ dev-python/ipython-genutils
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+ # Notebook interferes with our tests, pretend it does not exist
+ echo "raise ImportError" > notebook.py || die
+
+ epytest -p pytest_tornasync.plugin
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ # move /usr/etc stuff to /etc
+ mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
