[gentoo-commits] proj/kde:master commit in: kde-frameworks/kwallet/

[Andreas Sturmlechner]

commit:     b8001625d23216b264bb093b74a8b4e98cb2fae4
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  7 20:47:16 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan  8 22:59:34 2025 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=b8001625

kde-frameworks/kwallet: 6.10.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kwallet/kwallet-6.10.0.ebuild | 53 ++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/kde-frameworks/kwallet/kwallet-6.10.0.ebuild 
b/kde-frameworks/kwallet/kwallet-6.10.0.ebuild
new file mode 100644
index 0000000000..54a6467ab6
--- /dev/null
+++ b/kde-frameworks/kwallet/kwallet-6.10.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org optfeature
+
+DESCRIPTION="Framework providing desktop-wide storage for passwords"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="gpg +man X"
+
+DEPEND="
+       >=app-crypt/qca-2.3.9:2[qt6(+)]
+       dev-libs/libgcrypt:0=
+       >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+       =kde-frameworks/kcolorscheme-${KDE_CATV}*:6
+       =kde-frameworks/kconfig-${KDE_CATV}*:6
+       =kde-frameworks/kcoreaddons-${KDE_CATV}*:6
+       =kde-frameworks/kcrash-${KDE_CATV}*:6
+       =kde-frameworks/kdbusaddons-${KDE_CATV}*:6
+       =kde-frameworks/ki18n-${KDE_CATV}*:6
+       =kde-frameworks/knotifications-${KDE_CATV}*:6
+       =kde-frameworks/kservice-${KDE_CATV}*:6
+       =kde-frameworks/kwidgetsaddons-${KDE_CATV}*:6
+       =kde-frameworks/kwindowsystem-${KDE_CATV}*:6[X?]
+       gpg? ( app-crypt/gpgme:=[qt6(-)] )
+"
+RDEPEND="${DEPEND}
+       !${CATEGORY}/${PN}:5[-kf6compat(-)]
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${KDE_CATV}:6 )"
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake_use_find_package gpg Gpgmepp)
+               $(cmake_use_find_package man KF6DocTools)
+               -DWITH_X11=$(usex X)
+       )
+
+       ecm_src_configure
+}
+
+pkg_postinst() {
+       if [[ -z "${REPLACING_VERSIONS}" ]]; then
+               optfeature "Auto-unlocking after Plasma login" 
"kde-plasma/kwallet-pam"
+               optfeature "KWallet management" "kde-apps/kwalletmanager"
+               elog "For more information, read 
https://wiki.gentoo.org/wiki/KDE#KWallet";
+       fi
+       ecm_pkg_postinst
+}