commit: fd863e9055630cf4ed84c541ec77715079c12973
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 24 07:37:17 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 24 11:17:18 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd863e90
dev-python/rq: Bump to 2.1.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/rq/Manifest | 1 +
dev-python/rq/rq-2.1.0.ebuild | 73 +++++++++++++++++++++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index a5fc9d657db5..c4151750666f 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
DIST rq-2.0.0.tar.gz 639193 BLAKE2B
ec44a45618f4ba0cafd30d13d15db8efc26c35f41100019e94d28ac21ca0c6157df34c55fd9bc2c2afdd4752e815a45150c95840339744c005c297153795e598
SHA512
46878626ad939fdc3f31bfd04fab9d11f266a390fe75ea22fde62e1622607e715673a8f3d2e3aba78e489b861d16068836aea4eca5a88cd295d6b6ca61707a41
+DIST rq-2.1.0.tar.gz 640535 BLAKE2B
c269527d9863b7991be24cb6fac43cfbe8cea23fbbdbb8ff9699bce9653e014a0def7439ffbced1658bc54bb328119c2d3ddea9a83e0a3c2cbcd3d21500a1f28
SHA512
215c33e29ab18e8ebb693e4d9da2bf51750e1558ef20b13c4d301a803a5dda0e1c00edbfa019717043ea777e8c47e1772ab9334b12cc08e7fe9196121c6bd287
diff --git a/dev-python/rq/rq-2.1.0.ebuild b/dev-python/rq/rq-2.1.0.ebuild
new file mode 100644
index 000000000000..5cde9ca9c756
--- /dev/null
+++ b/dev-python/rq/rq-2.1.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing
background jobs"
+HOMEPAGE="
+ https://python-rq.org/
+ https://github.com/rq/rq/
+ https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/click-5.0[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-db/redis
+ dev-python/psutil[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unnecessary typechecking deps
+ sed -i -e '/types-/d' pyproject.toml || die
+}
+
+src_test() {
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+ local redis_test_config="daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1
+ "
+
+ # Spawn Redis itself for testing purposes
+ # NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+ # I'm not restricting tests yet because this doesn't happen for anyone
else AFAICT.
+ einfo "Spawning Redis"
+ einfo "NOTE: Port ${redis_port} must be free"
+ /usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+ # Run the actual tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # requires <sentry-sdk-2
+ tests/test_sentry.py::TestSentry::test_failure_capture
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
