commit: b155dcdedd99ee1f4c6d281a2b4c287e97a549cd
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 26 17:33:21 2024 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Nov 26 18:24:31 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b155dcde
kde-plasma/plasma-desktop: 6.2.4 version bump
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-plasma/plasma-desktop/Manifest | 1 +
.../plasma-desktop/plasma-desktop-6.2.4.ebuild | 183 +++++++++++++++++++++
2 files changed, 184 insertions(+)
diff --git a/kde-plasma/plasma-desktop/Manifest
b/kde-plasma/plasma-desktop/Manifest
index 7b65d049bb4b..b8ac389f3e70 100644
--- a/kde-plasma/plasma-desktop/Manifest
+++ b/kde-plasma/plasma-desktop/Manifest
@@ -1,3 +1,4 @@
DIST plasma-desktop-6.1.5.tar.xz 16144320 BLAKE2B
60b8ad791325e506551746790d23347c501caaa1550c470e5157e8902da07162691b30a36c53c6910d1daa32ea3e3801562d4acbf0feceaf35d72ad32662f809
SHA512
db5698874bd66be0194f868cc037af2521b924afb02a56036696504c2b3e8dec3d59ba9228203f7b0d08ffaaa36137f10081207fa79d748c5044b37063507b6f
DIST plasma-desktop-6.2.3.tar.xz 16334344 BLAKE2B
4dfa7c55e6d2bedcc1a52057bc86663b014b1aff54450cc521f0cb79814c08c1bf449408b3161b32d1b157a026f80c1a96dab0aad892322754d725ae3a3b4cb9
SHA512
72e8af1b71d3ed7e22f14ec044108a5a49daa4764586549e878378f4b4ffdfde72ef83c862102571e576724748c712b40e2f6dc302dafe68eee50c401d3f7645
+DIST plasma-desktop-6.2.4.tar.xz 16335912 BLAKE2B
95b7ca6b5c98f372ffe9c57f1d06bd0dc6ed7050891640fc4a523cc5373c904086f7c47cec84f168be2384798cde0eb6d8bdaa8f8cc0759baf3e52fdab888ffa
SHA512
9a766a2799bc96a803433a649884307fc40eb4e5d3c10578a3568ab433833b2a65462b5efb9275295dba5384eccb0365c52e7d98d42374c297adee9f42678f1e
DIST plasma-desktop-override-include-dirs-4.tar.xz 6360 BLAKE2B
8d4340f7b520ec2a4d47d7679028d5d75ceb141877248f7c411a082197ca9c0735ff2d21bd30333236c50dcae8bbdabd41164daa392b803504d2707ffd013960
SHA512
5273df12260d90e7aacc90b9ed7f6f1868c8996e2609229c59a771b3fb541b720f53fe2c2198d9d91870b05d06797bc4b2cec5afcf97d8b2b754f0da197584a1
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-6.2.4.ebuild
b/kde-plasma/plasma-desktop/plasma-desktop-6.2.4.ebuild
new file mode 100644
index 000000000000..f22e598f9785
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-6.2.4.ebuild
@@ -0,0 +1,183 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=6.6.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.2
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="KDE Plasma desktop"
+XORGHDRS="${PN}-override-include-dirs-4"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz";
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="ibus input_devices_wacom scim screencast sdl +semantic-desktop webengine"
+
+RESTRICT="test" # missing selenium-webdriver-at-spi
+
+# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
+# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
+COMMON_DEPEND="
+ dev-libs/icu:=
+ >=dev-qt/qt5compat-${QTMIN}:6[qml]
+ >=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,network,sql,widgets,xml]
+ >=dev-qt/qtdeclarative-${QTMIN}:6
+ >=dev-qt/qtsvg-${QTMIN}:6
+ >=kde-frameworks/attica-${KFMIN}:6
+ >=kde-frameworks/karchive-${KFMIN}:6
+ >=kde-frameworks/kauth-${KFMIN}:6
+ >=kde-frameworks/kbookmarks-${KFMIN}:6
+ >=kde-frameworks/kcmutils-${KFMIN}:6
+ >=kde-frameworks/kcodecs-${KFMIN}:6
+ >=kde-frameworks/kcompletion-${KFMIN}:6
+ >=kde-frameworks/kconfig-${KFMIN}:6
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:6
+ >=kde-frameworks/kcoreaddons-${KFMIN}:6
+ >=kde-frameworks/kcrash-${KFMIN}:6
+ >=kde-frameworks/kdbusaddons-${KFMIN}:6
+ >=kde-frameworks/kded-${KFMIN}:6
+ >=kde-frameworks/kglobalaccel-${KFMIN}:6
+ >=kde-frameworks/kguiaddons-${KFMIN}:6
+ >=kde-frameworks/ki18n-${KFMIN}:6
+ >=kde-frameworks/kiconthemes-${KFMIN}:6
+ >=kde-frameworks/kio-${KFMIN}:6
+ >=kde-frameworks/kitemmodels-${KFMIN}:6
+ >=kde-frameworks/kitemviews-${KFMIN}:6
+ >=kde-frameworks/kjobwidgets-${KFMIN}:6
+ >=kde-frameworks/knewstuff-${KFMIN}:6
+ >=kde-frameworks/knotifications-${KFMIN}:6
+ >=kde-frameworks/knotifyconfig-${KFMIN}:6
+ >=kde-frameworks/kpackage-${KFMIN}:6
+ >=kde-frameworks/kparts-${KFMIN}:6
+ >=kde-frameworks/krunner-${KFMIN}:6
+ >=kde-frameworks/kservice-${KFMIN}:6
+ >=kde-frameworks/ksvg-${KFMIN}:6
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+ >=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+ >=kde-frameworks/kxmlgui-${KFMIN}:6
+ >=kde-frameworks/solid-${KFMIN}:6
+ >=kde-frameworks/sonnet-${KFMIN}:6
+ >=kde-plasma/kwin-${PVCUT}:6
+ >=kde-plasma/libksysguard-${PVCUT}:6
+ >=kde-plasma/libplasma-${PVCUT}:6
+ >=kde-plasma/plasma-activities-${PVCUT}:6
+ >=kde-plasma/plasma-activities-stats-${PVCUT}:6
+ >=kde-plasma/plasma-workspace-${PVCUT}:6[screencast?]
+ >=kde-plasma/plasma5support-${PVCUT}:6
+ media-libs/libcanberra
+ x11-libs/libX11
+ x11-libs/libxcb
+ x11-libs/libXcursor
+ x11-libs/libXi
+ x11-libs/libxkbcommon
+ x11-libs/libxkbfile
+ ibus? (
+ app-i18n/ibus
+ dev-libs/glib:2
+ x11-libs/xcb-util-keysyms
+ )
+ input_devices_wacom? (
+ dev-libs/wayland
+ >=dev-qt/qtwayland-${QTMIN}:6
+ )
+ scim? ( app-i18n/scim )
+ sdl? ( media-libs/libsdl2[joystick] )
+ semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:6 )
+ webengine? (
+ kde-apps/kaccounts-integration:6
+ >=net-libs/accounts-qt-1.17[qt6(+)]
+ )
+"
+DEPEND="${COMMON_DEPEND}
+ dev-libs/boost
+ x11-base/xorg-proto
+ input_devices_wacom? ( >=dev-libs/wayland-protocols-1.25 )
+ test? (
+ >=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
+ >=kde-plasma/kactivitymanagerd-${PVCUT}:6
+ )
+"
+RDEPEND="${COMMON_DEPEND}
+ !<kde-plasma/kdeplasma-addons-5.25.50
+ !<kde-plasma/plasma-workspace-6.0.80
+ dev-libs/kirigami-addons:6
+ >=dev-qt/qtwayland-${QTMIN}:6
+ >=kde-frameworks/kirigami-${KFMIN}:6
+ >=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
+ >=kde-plasma/oxygen-${PVCUT}:6
+ kde-plasma/plasma-mimeapps-list
+ media-fonts/noto-emoji
+ sys-apps/util-linux
+ x11-apps/setxkbmap
+ x11-misc/xdg-user-dirs
+ screencast? ( >=kde-plasma/kpipewire-${PVCUT}:6 )
+ webengine? ( >=net-libs/signon-oauth2-0.25_p20210102[qt6(+)] )
+"
+BDEPEND="
+ dev-util/intltool
+ >=kde-frameworks/kcmutils-${KFMIN}:6
+ virtual/pkgconfig
+ input_devices_wacom? ( dev-util/wayland-scanner )
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-6.1.80-override-include-dirs.patch" # downstream
patch
+ "${FILESDIR}/${PN}-6.2.3-tablet-kcm-optional.patch" # bug 942817
+)
+
+src_prepare() {
+ ecm_src_prepare
+
+ if ! use ibus; then
+ sed -e "s/XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
+ -i applets/kimpanel/backend/ibus/CMakeLists.txt || die
+ fi
+
+ # TODO: try to get a build switch upstreamed
+ if ! use scim; then
+ sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_KCM_MOUSE_X11=ON
+ -DBUILD_KCM_TOUCHPAD_X11=ON
+ -DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ -DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
+ -DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON # not packaged
+ $(cmake_use_find_package ibus GLIB2)
+ -DBUILD_KCM_TABLET=$(usex input_devices_wacom)
+ $(cmake_use_find_package sdl SDL2)
+ $(cmake_use_find_package semantic-desktop KF6Baloo)
+ $(cmake_use_find_package webengine AccountsQt6)
+ $(cmake_use_find_package webengine KAccounts6)
+ )
+
+ ecm_src_configure
+}
+
+src_test() {
+ # parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+ # test_kio_fonts needs D-Bus, bug #634166
+ # lookandfeel-kcmTest is unreliable for a long time, bug #607918
+ local myctestargs=(
+ -j1
+ -E
"(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
+ )
+
+ ecm_src_test
+}
+
+pkg_postinst() {
+ if [[ -z "${REPLACING_VERSIONS}" ]]; then
+ optfeature "screen reader support" "app-accessibility/orca"
+ fi
+ ecm_pkg_postinst
+}
