Le 28/07/2022 à 22:19, Mikael Morin a écrit :
I propose to prepare something tomorrow.
Here you go. I haven’t found a procedure, a template or guidelines on
wg5-fortran.org, so I’m just asking questions as free text.
I have not put every combination of cases to limit the number of
examples, but an answer for each example should give a good picture.
Anything to correct or change? Anything to add?
Mikael
Hello,
we are contributors to gfortran. We have been discussing the
restrictions a processor is required to put on ASSOCIATED functions
calls with regards to rank mismatch in the thread at:
https://gcc.gnu.org/pipermail/fortran/2022-July/058012.html
The following discussions are on the same topic as well:
https://groups.google.com/g/comp.lang.fortran/c/BQfpeDZxX3Q
https://community.intel.com/t5/Intel-Fortran-Compiler/Intel-rejects-ASSOCIATED-pointer-target-for-non-equal-ranks/m-p/1402799/highlight/true#M162159
The position from Steve Lionel in the latter threads is that a processor
is required to reject an ASSOCIATED function call with arguments of
mismatching ranks as there is no bounds-remapping list.
Our understanding is that a processor shall accept it as long as it may
accept a corresponding pointer association statement with additional
bounds-remapping list.
Our poll of existing compilers shows the same disagreement, with two
accepting mismatching ranks (cray 14.0, nvidia 22.5) and two rejecting
them (NAG 7.0 & 7.1, Intel).
So we would like an official interpretation on this topic.
More specifically, for each program below, is a processor (at compile
time) required to reject it, allowed to reject it but not required to,
or required to accept it?
Harald Anlauf, Mikael Morin
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 1
! matrix pointer vs array target
program p
real, dimension(100), target :: array
real, dimension(:,:), pointer :: pmatrix => null()
print *, associated(pmatrix, array)
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 2
! array pointer vs matrix target
program p
real, dimension(20,5), target :: matrix
real, dimension(:), pointer :: parray => null()
print *, associated(parray, matrix)
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 3
! array pointer vs rank 2 non-contiguous target
program p
real, dimension(20,5), target :: matrix
real, dimension(:), pointer :: parray => null()
print *, associated(parray, matrix(1:20:3, 1:5:2))
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 4
! array pointer vs scalar target
program p
real, target :: scalar
real, dimension(:), pointer :: parray => null()
print *, associated(parray, scalar)
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 5
! scalar pointer vs array target
program p
real, dimension(100), target :: array
real, pointer :: pscalar => null()
print *, associated(pscalar, array)
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 6
! assumed rank (array) pointer vs matrix target
program p
real, dimension(20,5), target :: matrix
real, dimension(:), pointer :: parray => null()
call sub(parray)
contains
subroutine sub(ptr)
real, pointer :: ptr(..)
print *, associated(ptr, matrix)
end subroutine sub
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 7
! assumed rank (scalar) pointer vs array target
program p
real, dimension(100), target :: array
real, pointer :: pscalar => null()
call sub(pscalar)
contains
subroutine sub(ptr)
real, pointer :: ptr(..)
print *, associated(ptr, array)
end subroutine sub
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Example 8
! assumed rank (array) pointer vs scalar target
program p
real, target :: scalar
real, dimension(:), pointer :: parray => null()
call sub(parray)
contains
subroutine sub(ptr)
real, pointer :: ptr(..)
print *, associated(ptr, scalar)
end subroutine sub
end
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
