Package: libktoblzcheck
Version: 1.6-3
Severity: important
The current version of libktoblzcheck fails to build on
GNU/kFreeBSD, because of outdated libtool.
The version of libtool in libktoblzcheck is too old to correctly
support Debian GNU/kFreeBSD. libtool 1.5.2-1 or later is need.
Here is how to update the libtool in your package (Make sure you are
using libtool 1.5.2-1 or later). As some functions where misplaced into
aclocal.m4 instead of acinclude.m4, you will find attached the correct
acinclude.m4 built by hand from aclocal.m4. Then, you will have to run:
libtoolize -c -f
aclocal-1.7
autoconf2.50
It would also be nice if you can ask upstream to update libtool
in their next release.
Thanks for your cooperation
-- System Information:
Debian Release: testing/unstable
Architecture: kfreebsd-i386 (i686)
Shell: /bin/sh linked to /bin/bash
Kernel: GNU/kFreeBSD 5.3-17
Locale: LANG=fr_FR.UTF-8, LC_CTYPE=fr_FR.UTF-8 (charmap=UTF-8)
# $Id: os.m4,v 1.2 2004/05/04 13:41:10 cstim Exp $
# (c) 2002 Martin Preuss<[EMAIL PROTECTED]>
# These functions guess your operation system
AC_DEFUN([AQ_CHECK_OS],[
dnl IN:
dnl - AC_CANONICAL_SYSTEM muste be called before
dnl OUT:
dnl Variables:
dnl OSYSTEM: Short name of your system (subst)
dnl OS_TYPE: either "posix" or "windows" (subst)
dnl MAKE_DLL_TARGET: under windows this is set to "dll" (subst)
dnl INSTALL_DLL_TARGET: under Windows this is set to "dll-install" (subst)
dnl Defines:
dnl OS_NAME: full name of your system
dnl OS_SHORTNAME: short name of your system
dnl Depending on your system one of the following is defined in addition:
dnl OS_LINUX, OS_OPENBSD, OS_FREEBSD, OS_BEOS, OS_WIN32
# check for OS
AC_MSG_CHECKING([target system type])
OSYSTEM=""
OS_TYPE=""
MAKE_DLL_TARGET=""
INSTALL_DLL_TARGET=""
AC_DEFINE_UNQUOTED(OS_NAME,"$target", [target system])
case "$target" in
*-linux*)
OSYSTEM="linux"
AC_DEFINE(OS_LINUX,1,[if linux is used])
OS_TYPE="posix"
;;
*-openbsd*)
OSYSTEM="openbsd"
AC_DEFINE(OS_OPENBSD,1,[if OpenBSD is used])
OS_TYPE="posix"
;;
*-freebsd*)
OSYSTEM="freebsd"
AC_DEFINE(OS_FREEBSD,1,[if FreeBSD is used])
OS_TYPE="posix"
;;
*-beos*)
OSYSTEM="beos"
AC_DEFINE(OS_BEOS,1,[if BeOS is used])
OS_TYPE="posix"
;;
*-win32*)
OSYSTEM="windows"
AC_DEFINE(OS_WIN32,1,[if WIN32 is used])
OS_TYPE="windows"
AC_DEFINE_UNQUOTED(BUILDING_DLL,1,[if DLL is to be built])
MAKE_DLL_TARGET="dll"
INSTALL_DLL_TARGET="dll-install"
;;
*-mingw32*)
OSYSTEM="windows"
AC_DEFINE(OS_WIN32,1,[if WIN32 is used])
OS_TYPE="windows"
AC_DEFINE_UNQUOTED(BUILDING_DLL,1,[if DLL is to be built])
MAKE_DLL_TARGET="dll"
INSTALL_DLL_TARGET="dll-install"
;;
*-palmos*)
OSYSTEM="palmos"
AC_DEFINE(OS_PALMOS,1,[if PalmOS is used])
OS_TYPE="palmos"
;;
*)
AC_MSG_WARN([Sorry, but target $target is not supported.
Please report if it works anyway. We will assume that your system
is a posix system and continue.])
OSYSTEM="unknown"
OS_TYPE="posix"
;;
esac
AC_SUBST(OSYSTEM)
AC_DEFINE_UNQUOTED(OS_SHORTNAME,"$OSYSTEM",[target system])
AC_SUBST(OS_TYPE)
AC_DEFINE_UNQUOTED(OS_TYPE,"$OS_TYPE",[system type])
AC_SUBST(MAKE_DLL_TARGET)
AC_SUBST(INSTALL_DLL_TARGET)
AC_MSG_RESULT($OS_TYPE)
])
# (c) 2004 Martin Preuss<[EMAIL PROTECTED]>
# These functions retrieve some important paths
AC_DEFUN([AQ_WINDOZE_GETPATH], [
dnl IN:
dnl - $1: type of path to get:
dnl - windows: windows path
dnl - system: windows/system directory
dnl - home: users home directory
dnl - $2: default value
dnl OUT:
dnl - aq_windoze_path: path retrieved
dnl
rm -f conf.winpath
AC_TRY_RUN([
#include <windows.h>
#include <string.h>
#include <stdio.h>
#include <stdlib.h>
int main (){
char buffer[260];
const char *choice = "$1";
FILE *f;
buffer[0]=0;
if (strlen("$2")) {
if (strlen("$2")>=sizeof(buffer)) {
printf("path is too long ($2)\n");
exit(1);
}
strcpy(buffer, "$2");
}
else {
if (strcasecmp(choice, "windows")==0) {
GetWindowsDirectory(buffer, sizeof(buffer));
}
else if (strcasecmp(choice, "system")==0) {
GetSystemDirectory(buffer, sizeof(buffer));
}
else if (strcasecmp(choice, "home")==0) {
GetWindowsDirectory(buffer, sizeof(buffer));
}
else {
printf("Unknown type \"$1\"\n");
exit(1);
}
}
f=fopen("conf.winpath", "w+");
if (!f) {
printf("Could not create file conf.winpath\n");
exit(1);
}
fprintf(f, "%s", buffer);
if (fclose(f)) {
printf("Could not close file.\n");
exit(1);
}
exit(0);
}
],
[aq_windoze_path="`cat conf.winpath`"],
[AC_MSG_ERROR(Could not determine path for $1)],
[aq_windoze_path="$2"; AC_MSG_RESULT([Crosscompiling, assuming $2])]
)
rm -f conf.winpath
])
AC_DEFUN([AQ_WINDOZE_GETPATH_MINGW], [
dnl IN:
dnl - $1: type of path to get:
dnl - windows: windows path
dnl - system: windows/system directory
dnl - home: users home directory
dnl - $2: default value
dnl OUT:
dnl - aq_windoze_path: path retrieved
dnl
rm -f conf.winpath
AC_TRY_RUN([
#include <windows.h>
#include <string.h>
#include <stdio.h>
#include <stdlib.h>
/* #include <shlobj.h> */
int main (){
char buffer[260];
char buffer2[260+2];
const char *choice = "$1";
char *p;
char *tp;
FILE *f;
int lastWasSlash;
buffer[0]=0;
if (strlen("$2")) {
if (strlen("$2")>=sizeof(buffer)) {
printf("path is too long ($2)\n");
exit(1);
}
strcpy(buffer, "$2");
}
else {
if (strcasecmp(choice, "windows")==0) {
GetWindowsDirectory(buffer, sizeof(buffer));
}
else if (strcasecmp(choice, "system")==0) {
GetSystemDirectory(buffer, sizeof(buffer));
}
else if (strcasecmp(choice, "home")==0) {
GetWindowsDirectory(buffer, sizeof(buffer));
}
else {
printf("Unknown type \"$1\"\n");
exit(1);
}
}
/* create mingw path */
tp=buffer2;
p=buffer;
if (strlen(buffer)>1) {
if (buffer[1]==':') {
*tp='/';
tp++;
*tp=buffer[0];
tp++;
p+=2;
}
}
lastWasSlash=0;
while(*p) {
if (*p=='\\\\' || *p=='/') {
if (!lastWasSlash) {
*tp='/';
tp++;
lastWasSlash=1;
}
}
else {
lastWasSlash=0;
*tp=*p;
tp++;
}
p++;
} /* while */
*tp=0;
f=fopen("conf.winpath", "w+");
if (!f) {
printf("Could not create file conf.winpath\n");
exit(1);
}
fprintf(f, "%s", buffer2);
if (fclose(f)) {
printf("Could not close file.\n");
exit(1);
}
exit(0);
}
],
[aq_windoze_path=`cat conf.winpath`],
[AC_MSG_ERROR(Could not determine path for $1)],
[aq_windoze_path="$2"; AC_MSG_RESULT([Crosscompiling, assuming $2])]
)
rm -f conf.winpath
])
AC_DEFUN([ACX_WINDOWS_PATHS],[
dnl IN:
dnl - AC_CANONICAL_SYSTEM muste be called before
dnl OUT:
dnl Variables (subst):
dnl WIN_PATH_HOME : path and name of the Windoze home folder
dnl WIN_PATH_HOME_MINGW : path and name of the Windoze home folder
dnl WIN_PATH_WINDOWS : path and name of the Windoze system folder
dnl WIN_PATH_WINDOWS_MINGW : path and name of the Windoze system folder
dnl WIN_PATH_SYSTEM : path and name of the Windoze folder
dnl WIN_PATH_SYSTEM_MINGW : path and name of the Windoze folder
dnl Defines:
dnl WIN_PATH_HOME : path and name of the Windoze home folder
dnl WIN_PATH_WINDOWS : path and name of the Windoze system folder
dnl WIN_PATH_SYSTEM : path and name of the Windoze folder
# presets
AC_ARG_WITH(home-path, [ --with-home-path=DIR specify the home directory for a user],
[aq_windoze_path_home="$withval"])
AC_ARG_WITH(system-path, [ --with-system-path=DIR specify the system directory],
[aq_windoze_path_system="$withval"])
AC_ARG_WITH(windows-path, [ --with-windows-path=DIR specify the windows directory],
[aq_windoze_path_windows="$withval"])
# home directory
AC_MSG_CHECKING([for windoze home path (program)])
AC_CACHE_VAL(gwenhywfar_cv_path_home,
[
AQ_WINDOZE_GETPATH(home, [$aq_windoze_path_home])
gwenhywfar_cv_path_home="$aq_windoze_path"
])
WIN_PATH_HOME="$gwenhywfar_cv_path_home"
AC_MSG_RESULT([$WIN_PATH_HOME])
AC_MSG_CHECKING([for windoze home path (mingw)])
AC_CACHE_VAL(gwenhywfar_cv_path_home_mingw,
[
AQ_WINDOZE_GETPATH_MINGW(home, [$aq_windoze_path_home])
gwenhywfar_cv_path_home_mingw="$aq_windoze_path"
])
WIN_PATH_HOME_MINGW="$gwenhywfar_cv_path_home_mingw"
AC_MSG_RESULT([$WIN_PATH_HOME_MINGW])
# windows directory
AC_MSG_CHECKING([for windoze windows path (program)])
AC_CACHE_VAL(gwenhywfar_cv_path_windows,
[
AQ_WINDOZE_GETPATH(windows, [$aq_windoze_path_windows])
gwenhywfar_cv_path_windows="$aq_windoze_path"
])
WIN_PATH_WINDOWS="$gwenhywfar_cv_path_windows"
AC_MSG_RESULT([$WIN_PATH_WINDOWS])
AC_MSG_CHECKING([for windoze windows path (mingw)])
AC_CACHE_VAL(gwenhywfar_cv_path_windows_mingw,
[
AQ_WINDOZE_GETPATH_MINGW(windows, [$aq_windoze_path_windows])
gwenhywfar_cv_path_windows_mingw="$aq_windoze_path"
])
WIN_PATH_WINDOWS_MINGW="$gwenhywfar_cv_path_windows_mingw"
AC_MSG_RESULT([$WIN_PATH_WINDOWS_MINGW])
# windows system directory
AC_MSG_CHECKING([for windoze system path (program)])
AC_CACHE_VAL(gwenhywfar_cv_path_system,
[
AQ_WINDOZE_GETPATH(system, [$aq_windoze_path_system])
gwenhywfar_cv_path_system="$aq_windoze_path"
])
WIN_PATH_SYSTEM="$gwenhywfar_cv_path_system"
AC_MSG_RESULT([$WIN_PATH_SYSTEM])
AC_MSG_CHECKING([for windoze system path (mingw)])
AC_CACHE_VAL(gwenhywfar_cv_path_system_mingw,
[
AQ_WINDOZE_GETPATH_MINGW(system, [$aq_windoze_path_system])
gwenhywfar_cv_path_system_mingw="$aq_windoze_path"
])
WIN_PATH_SYSTEM_MINGW="$gwenhywfar_cv_path_system_mingw"
AC_MSG_RESULT([$WIN_PATH_SYSTEM_MINGW])
# finish variables
AC_SUBST(WIN_PATH_HOME)
AC_DEFINE_UNQUOTED(WIN_PATH_HOME, "$WIN_PATH_HOME", [home path])
AC_SUBST(WIN_PATH_HOME_MINGW)
AC_SUBST(WIN_PATH_WINDOWS)
AC_DEFINE_UNQUOTED(WIN_PATH_WINDOWS, "$WIN_PATH_WINDOWS", [windows path])
AC_SUBST(WIN_PATH_WINDOWS_MINGW)
AC_SUBST(WIN_PATH_SYSTEM)
AC_DEFINE_UNQUOTED(WIN_PATH_SYSTEM, "$WIN_PATH_SYSTEM", [system path])
AC_SUBST(WIN_PATH_SYSTEM_MINGW)
])
dnl Available from the GNU Autoconf Macro Archive at:
dnl http://www.gnu.org/software/ac-archive/htmldoc/ac_c_long_long.html
dnl
AC_DEFUN([AC_C_LONG_LONG],
[AC_CACHE_CHECK(for long long int, ac_cv_c_long_long,
[if test "$GCC" = yes; then
ac_cv_c_long_long=yes
else
AC_TRY_COMPILE(,[long long int i;],
ac_cv_c_long_long=yes,
ac_cv_c_long_long=no)
fi])
if test $ac_cv_c_long_long = yes; then
AC_DEFINE(HAVE_LONG_LONG, 1, [Defined if the compiler supports long long int])
fi
])
