2008-09-26 Bruno Haible <[EMAIL PROTECTED]>
* modules/sigpipe: New file.
* m4/sigpipe.m4: New file.
============================ modules/sigpipe ==================================
Description:
Emulation of POSIX compatible SIGPIPE behaviour.
Files:
m4/sigpipe.m4
Depends-on:
signal
sigprocmask
stdio
unistd
configure.ac:
gl_SIGNAL_SIGPIPE
dnl Define the C macro GNULIB_SIGPIPE to 1.
gl_MODULE_INDICATOR([sigpipe])
dnl Define the substituted variable GNULIB_SIGNAL_H_SIGPIPE to 1.
AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
GNULIB_SIGNAL_H_SIGPIPE=1
dnl Define the substituted variable GNULIB_STDIO_H_SIGPIPE to 1.
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
GNULIB_STDIO_H_SIGPIPE=1
dnl Define the substituted variable GNULIB_UNISTD_H_SIGPIPE to 1.
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
GNULIB_UNISTD_H_SIGPIPE=1
Makefile.am:
Include:
<signal.h>
License:
LGPL
Maintainer:
Bruno Haible
============================= m4/sigpipe.m4 ===================================
# sigpipe.m4 serial 1
dnl Copyright (C) 2008 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl Tests whether SIGPIPE is provided by <signal.h>.
dnl Sets gl_cv_header_signal_h_SIGPIPE.
AC_DEFUN([gl_SIGNAL_SIGPIPE],
[
dnl Use AC_REQUIRE here, so that the default behavior below is expanded
dnl once only, before all statements that occur in other macros.
AC_REQUIRE([gl_SIGNAL_SIGPIPE_BODY])
])
AC_DEFUN([gl_SIGNAL_SIGPIPE_BODY],
[
AC_REQUIRE([AC_PROG_CC])
AC_CACHE_CHECK([for SIGPIPE], gl_cv_header_signal_h_SIGPIPE, [
AC_EGREP_CPP(booboo,[
#include <signal.h>
#if !defined SIGPIPE
booboo
#endif
],
[gl_cv_header_signal_h_SIGPIPE=no],
[gl_cv_header_signal_h_SIGPIPE=yes])
])
])
===============================================================================
