Sorry about the missing patch. Attached.
Derek
Derek Price wrote:
>The attached patch tests for the glibc glob symlink bug and uses the
>GNULIB glob module when it is found. It also uses the autoconf cache
>more. It tests out on a platform with and without the bug. I'll commit
>it soon if there are no comments.
>
>2005-07-13 Derek Price <[EMAIL PROTECTED]>
>
> * glob.m4 (gl_GLOB): Cache glob interface check result. Add
>check for
> glob symlink bug.
>
>Regards,
>
>Derek
>
>
>
Index: m4/glob.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/glob.m4,v
retrieving revision 1.2
diff -u -p -r1.2 glob.m4
--- m4/glob.m4 31 May 2005 21:01:36 -0000 1.2
+++ m4/glob.m4 13 Jul 2005 21:17:11 -0000
@@ -25,11 +25,45 @@ AC_DEFUN([gl_GLOB],
AC_CHECK_HEADERS([glob.h], [], [GLOB_H=glob.h])
if test -z "$GLOB_H"; then
- AC_COMPILE_IFELSE(
+ AC_CACHE_CHECK([GNU glob interface version], [gl_cv_glob_interface],
+[ AC_COMPILE_IFELSE(
[[#include <gnu-versions.h>
char a[_GNU_GLOB_INTERFACE_VERSION == 1 ? 1 : -1];]],
- [], [GLOB_H=glob.h])
+ [gl_cv_glob_interface=compatible],
+ [gl_cv_glob_interface=incompatible])])
+
+ if test "$gl_cv_glob_interface" = "incompatible"; then
+ GLOB_H=glob.h
+ fi
fi
+
+ if test -z "$GLOB_H"; then
+ AC_CACHE_CHECK([whether glob lists broken symlinks],
+ [gl_cv_glob_lists_symlinks],
+[ if ln -s conf-doesntexist conf$$-globtest 2>/dev/null; then
+ gl_cv_glob_lists_symlinks=yes
+ else
+ # If we can't make a symlink, then we cannot test this issue. Be
+ # pessimistic about this.
+ gl_cv_glob_lists_symlinks=no
+ fi
+
+ if test $gl_cv_glob_lists_symlinks = yes; then
+ AC_RUN_IFELSE(
+AC_LANG_PROGRAM(
+[[#include <stddef.h>
+#include <glob.h>]],
+[[glob_t found;
+if (glob ("conf*-globtest", 0, NULL, &found) == GLOB_NOMATCH) return 1;]]),
+ [], [gl_cv_glob_lists_symlinks=no], [gl_cv_glob_lists_symlinks=no])
+ fi])
+
+ if test $gl_cv_glob_lists_symlinks = no; then
+ GLOB_H=glob.h
+ fi
+ fi
+
+ rm -f conf$$-globtest
if test -n "$GLOB_H"; then
gl_GLOB_SUBSTITUTE
_______________________________________________
bug-gnulib mailing list
bug-gnulib@gnu.org
http://lists.gnu.org/mailman/listinfo/bug-gnulib
